Exercice 4

On défnit la paramétrisation, puis on construit le support partiel et sir la totalité des paramètres

>

restart;

>	x:=t->R*(t-sin(t));y:=t->R*(1-cos(t));

>	total:=[x(t),y(t),t=-15..15]: partiel:=[x(t),y(t),t=0..Pi]:

>	R:=1:plot([total,partiel],color=[blue,red],thickness=[1,2]);R:='R':

Calculons le vecteur vitesse

>	V:=unapply([D(x)(t),D(y)(t)],t);

Cet arc n'est donc pas régulier les points de parametre multiple pair de Pi sont stationnaires

>

vérifions que (sin t/2, cos t/2) dirige les tangentes en des points régulierrs.

>	Vu:=subs(t=2*u,V(t));

>	Vu:=expand(Vu);

>	Vt:=subs(u=t/2,Vu);

Vu que t n'est pas multiple pair de Pi on peut simplifier cettte expression par R sint/2, ce qui nous donne encore un vecteur directeur de la tangente

>	direct_t:=(1/(2*R*sin(t/2)))*Vt;

>	direct_t:=simplify(expand(direct_t));

CQFD pour les points réguliers.

Regardons le cas des points stationnaires

Vérifions la limite du taux d'accroissement en 2k*Pi avec k entier

>	assume(k,integer):

>	Limit((y(t)-y(2*k*Pi))/(x(t)-x(2*k*Pi)),t=2*k*Pi)=limit((y(t)-y(2*k*Pi))/(x(t)-x(2*k*Pi)),t=2*k*Pi);

Essayons alors celle de la valeur absolue du taux d'accroissment

>	Limit(abs((y(t)-y(2*k*Pi))/(x(t)-x(2*k*Pi))),t=2*k*Pi)=limit(abs((y(t)-y(2*k*Pi))/(x(t)-x(2*k*Pi))),t=2*k*Pi);

On en déduit donc une tangente verticale aux points de paramètre 2*k*Pi (k entier), d'où un vecteur directeur pour les points stationnaire

>	direct_2kpi:=[0,(-1)^k];

>	eval(subs(t=2*k*Pi,direct_t));

Or ceci correspond encore à (sin t/2, cos t/2)

>	eval(subs(t=2*k*Pi,direct_t));

CQFD... Pour tous les points

>

La normale à en M(t) à la courbe est la droite passant par M(t) de vecteur normal direct_t, d'où l'équation cartésienne

>	with(linalg):

>	Eq_normale:=dotprod(vector([x-x(t),y-y(t)]),vector(direct_t),orthogonal)=0;

>	Eq_normale:=expand(Eq_normale);

>

Voici l'équaion obtenu à partir des coefficiesnt dérivés

>	Eq_normale_prime:=diff(Eq_normale,t);

>	systeme:={Eq_normale,Eq_normale_prime};

>	Lambda:=solve(systeme,{x,y});

>	Lambda:=simplify(Lambda);

>	Lambda:=combine(Lambda);

>	Lambda:=factor(Lambda);

On reconnait la paramétrisation d'une  cycloïde, en effet

>	X:=unapply(rhs(Lambda[2]),t);Y:=unapply(rhs(Lambda[1]),t);

Comparons les paramétrisations f de la cicloide initiale et celle notée g de l'ensemble Lambda

>	f:=t->[x(t),y(t)]:g:=t->[X(t),Y(t)]:

>	ecart:=g(Pi+t)-f(t);

>	u:=simplify(ecart);

Ainsi Lambda est l'image de notre cycloïde par translation  de vecteur u(R*Pi,-2R)

Tracons ces deux courbes

>	lambda:=[X(t),Y(t),t=-15..15];

>	R:=1:plot([lambda,total], color=[red,blue]);R:='R':

>

On peut vérifier que chaque Normale à la première cycloide est en fait une tangente  à la deuxième

>	Eq_normale_bis:=subs(t=t*15/50,Eq_normale):

>	R:=1:Normales:={seq(Eq_normale_bis,t=-50..50)}:R:='R':

>

>	with(plots):implicitplot(Normales,x=-20..20,y=-2..2);

Ci-dessus on a tracé une centaine de normales à la première cycloide, et on voit se profiler la deuxième, on dit qu'il s'git de l'enveloppe de la famille de droites normales à la première cycloide