ex7.mw

Exercice 7

On définit la paramétrisation

> restart;

> x:=t->t/(1+t^3);y:=t->(t^2)/(1+t^3);

x := proc (t) options operator, arrow; t/(1+t^3) end proc

y := proc (t) options operator, arrow; t^2/(1+t^3) end proc

Domaine d'Etude

Réduisons l'intervalle d'étude à -1..1, En effet

> [x(1/t),y(1/t)]=[y(t),x(t)];

[1/(t*(1+1/t^3)), 1/(t^2*(1+1/t^3))] = [t^2/(1+t^3), t/(1+t^3)]

> simplify(%);

[t^2/(1+t^3), t/(1+t^3)] = [t^2/(1+t^3), t/(1+t^3)]

> evalb(%);

true

Donc la partie de courbe correspondant aux autres paramétres  se déduira par symétrie / à la première bissectrice

Calculons le vecteur vitesse

> Vt:=[D(x)(t),D(y)(t)];

Vt := [1/(1+t^3)-3*t^3/(1+t^3)^2, 2*t/(1+t^3)-3*t^4/(1+t^3)^2]

> Vt:=simplify(Vt);

Vt := [-(-1+2*t^3)/(1+t^3)^2, -t*(-2+t^3)/(1+t^3)^2]

> V:=unapply(Vt,t);

V := proc (t) options operator, arrow; [-(-1+2*t^3)/(1+t^3)^2, -t*(-2+t^3)/(1+t^3)^2] end proc

>

Cette courbe est donc régulière

Tangente aux points  A=M(0)=(0,0), B=M((1/2)^(1/3))  et C=M(1)=(1/2,1/2)

Ces tangentes sont dirigées par les vecteurs

> V(0);V((1/2)^(1/3));V(1);

[1, 0]

[0, 1/3*2^(2/3)]

[(-1)/4, 1/4]

D'où les équations paramétrées des tangentes

> XTA:=x(0)+t*op(1,V(0));YTA:=y(0)+t*op(2,V(0));

XTA := t

YTA := 0

> XTB:=x((1/2)^(1/3))+t*op(1,V((1/2)^(1/3)));YTB:=y((1/2)^(1/3))+t*op(2,V((1/2)^(1/3)));

XTB := 1/3*2^(2/3)

YTB := 1/3*2^(1/3)+1/3*t*2^(2/3)

> XTC:=x(1)+t*op(1,V(1));YTC:=y(1)+t*op(2,V(1));

XTC := 1/2-1/4*t

YTC := 1/2+1/4*t

> EqTA:=[XTA,YTA,t=-infinity..infinity]:EqTB:=[XTB,YTB,t=-infinity..infinity]:EqTC:=[XTC,YTC,t=-infinity..infinity]:

Branches Infinies éventuelles

> Limit('x'(t),t=-1,right)=limit(x(t),t=-1,right),Limit('y'(t),t=-1,right)=limit(y(t),t=-1,right) ;

Limit(x(t), t = -1, right) = -infinity, Limit(y(t), t = -1, right) = infinity

D'où une branche infinie lorsque t->-1^+,

Calculons la limite du taux y/x

> Limit('y'(t)/'x'(t),t=-1,right)=limit(y(t)/x(t),t=-1,right);

Limit(y(t)/x(t), t = -1, right) = -1

La courbe admet donc une direction asymptotique la droite d'équation y=-x

. Calculons alors la limite suivante

> Limit('y'(t)+'x'(t),t=-1,right)=limit(y(t)+x(t),t=-1,right);

Limit(y(t)+x(t), t = -1, right) = (-1)/3

Donc la courbe admet une asymptote oblique d'équation y=-x-1/3... d'où son équation paramétrique

> XA:=t;YA:=-t-1/3;

XA := t

YA := -t-1/3

> EqA:=[XA,YA,t=-infinity..infinity]:

Position Relative: pour cela on étudie le signe de y(tau)+x(tau)+1/3 pour tau proche de -1 (par valeurs supérieures)

> assume(tau>-1):is(y(tau)+x(tau)+1/3>0);

true

#Vérifions le à l'aide de son expression algébrique:

> factor(y(t)+x(t)+1/3);

1/3*(1+t)^2/(t^2-t+1)

On a donc l'arc est "au dessus" de cette asymptote... Par symétrie / Ox on a la même asymptote et la même position relative pour t->infinity

Etude des variations de x et y

> plot(x,-1..1,-5..1);

[Plot]

> plot(y,-1..1,-1..10);

[Plot]

> varx:=D(x)(t)/abs(D(x)(t)):

> vary:=D(y)(t)/abs(D(y)(t))/2:

On trace en rouge le signe x' et en vert le signe de y'

> plot([varx,vary],t=-1..1,discont=true,thickness=[3,3]);

[Plot]

>

support de la courbe

> total:=[x(t),y(t),t=-infinity..infinity]: partiel:=[x(t),y(t),t=-1..1]:

> plot([total,partiel,EqTA,EqTB,EqTC,EqA],-0.6..0.6,-0.6..0.6,color=[blue,red,black,black,black,green],thickness=[1,2,2,2,2,2]);

[Plot]

> plot(total,-0.5..0.5,-0.5..0.5,axes=none);

[Plot]

Attention MAPLE semble ajouter à la courbe son asymptote!!!

De plus par manque de precision certains points de la courbe sont manquants ou approximatifs: car représentés en lignes brisées

>